Nick/Address Tracking

mIRC sorun, ders, addon ve script paylaşım bölümü..
Post Reply
User avatar
SaNCaK
Admin
Admin
Posts: 7
Joined: 21 Sep 2010, 17:22

Nick/Address Tracking

Post by SaNCaK » 22 Nov 2016, 20:19

Code: Select all

on *:LOAD: { 
  echo -a _____________________________________________________
  echo -a 4,1[15,1 SaNCaK 4,1] 0,1 Loading Add-On... 
  echo -a 4,1[15,1 SaNCaK 4,1] 0,1 Add-on: 09 Nick/Address Tracking  15 Add-On  
  echo -a 4,1[15,1 SaNCaK 4,1] 0,1 You are running mIRC $version on $os  $+ .
  echo -a 4,1[15,1 SaNCaK 4,1] 0,1 Coder: 15SaNCaK 0,1 E-Mail: [email protected] 
  echo -a 4,1[15,1 SaNCaK 4,1] 0,1 Copyright © 200915 http://www.sancak.gen.tr
  echo -a ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
  hmake addtrack 10000
} 
menu channel,menubar,nicklist {
  Nick Tracking
  .$iif($group(#Addtrack) == on,$style(1)) Show used nicks on join (*@host): {
    var %status = $iif($group(#Addtrack) == on,Disable,Enable)
    $+(.,%status) #Addtrack
    echo 7 -at * Users previous nicks will $iif(%status == Disable,no longer,now) be shown when they join.
  }
  .-
  .$iif($1,Check nicks for $1):CheckNicks $1
  .Check nicks for an address: {
    CheckNicks $+(*!,$$?="Enter the hostmask you want to check in the format [email protected]*")
  }
}

on *:start: {
  hmake addtrack 10000
  if ($isfile(addtrack.hsh)) hload addtrack addtrack.hsh
}

on *:exit: { 
  if ($hget(addtrack)) hsave -o addtrack addtrack.hsh
}

#Addtrack off
on *:join:#: {
  if ($wildsite iswm $address($me,5)) return
  var %mask = $mask($fulladdress,2)
  if ($hget(addtrack,%mask)) {
    var %usednicks = $ifmatch
    if (%usednicks != $nick) && ($group(#Addtrack) == on) echo 14 -t $chan 14 [Nick Tracking]  $nick  has also used the nick[s]: 7 $+ $remtok(%usednicks,$nick,1,44)
    if (!$istok(%usednicks,$nick,44)) hadd -m addtrack %mask $addtok(%usednicks,$nick,44)
    if ($numtok(%usednicks,44) > 10) hadd -m addtrack %mask $deltok(%usednicks,1,44)
  }
  else {
    hadd -m addtrack %mask $nick
  }
}

on *:nick: {
  if ($wildsite iswm $address($me,5)) return
  var %mask = $mask($fulladdress,2)
  if ($hget(addtrack,%mask)) {
    var %usednicks = $ifmatch
    if (!$istok(%usednicks,$newnick,44)) hadd -m addtrack %mask $addtok(%usednicks,$newnick,44)
    if ($numtok(%usednicks,44) > 10) hadd -m addtrack %mask $deltok(%usednicks,1,44)
  }
  else {
    hadd -m addtrack %mask $newnick
  }
}
#Addtrack end

alias CheckNicks {
  if (*!*@* iswm $1) {
    var %mask = $mask($1,2)
    if (!$hget(addtrack,%mask)) echo 4 -ta [Nick Tracking (*@host)] No entry found for $1
    else echo 10 -ta Address $1 has used the nick[s]: 7 $+ $hget(addtrack,$1)
  }
  elseif (!$hget(addtrack,$address($1,2))) echo 4 -ta [Nick Tracking (*@host)] No entry found for $1
  elseif ($hget(addtrack,$address($1,2)) != $1) {
    var %usednicks = $ifmatch
    echo 10 -ta [Nick Tracking (*@host)] $1 has also used the nick[s]: 7 $+ $remtok(%usednicks,$1,1,43)
  }
  else echo 10 -ta [Nick Tracking (*@host)] $1 has not been seen using any other nicks.
}

Post Reply

Who is online

Users browsing this forum: No registered users and 1 guest